DCLibraries/dCArun/dCArun.pro

QT       += core
QT      += serialport
QT      +=network
    # for TCP-IP

TARGET  = dCArun
TEMPLATE = app

VERSION = "1.0.0"

DESTDIR=$${_PRO_FILE_PWD_}/../build


CONFIG += c++11
CONFIG += PTU5

# _FORTIFY_SOURCE requires compiling with optimization (-O) [-Wcpp]
QMAKE_CXXFLAGS += -O

INCLUDEPATH += ../include


win32 {
    BUILD_DATE=$$system("date /t")
    BUILD_TIME=$$system("time /t")
    GIT_COMMIT=""
    EXTENDED_VERSION=""
} else {
    BUILD_DATE=$$system("date +%d-%m-%y")
    BUILD_TIME=$$system("date +%H:%M:%S")

    GIT_COMMIT=$$system("git log -1 --format=oneline | cut -d' ' -f1")
    EXTENDED_VERSION="$${VERSION}-$${GIT_COMMIT}"
}

DEFINES+=APP_VERSION=\\\"$$VERSION\\\"
DEFINES+=APP_BUILD_DATE=\\\"$$BUILD_DATE\\\"
DEFINES+=APP_BUILD_TIME=\\\"$$BUILD_TIME\\\"
DEFINES+=APP_EXTENDED_VERSION=\\\"$$EXTENDED_VERSION\\\"

SOURCES += \
    CArun.cpp \
    main.cpp \
    tslib.cpp \
    datei.cpp

HEADERS += \
    CArun.h \
    guidefs.h \
    tslib.h \
    versionHistory.txt \
    datei.h \
    plugin.h